« 2010年4月 | トップページ | 2012年3月 »

2010年12月

Screen capture program by AutoIt

; ScrCap : Capture screen and save program by AutoIt

#include <GUIConstantsEx.au3>
#include <ScreenCapture.au3>
#Include <Timers.au3>
#Include <Date.au3>

Opt('MustDeclareVars', 1)
Opt("GUIOnEventMode", 1)
Opt("WinTitleMatchMode", 3)     ;1=start, 2=subStr, 3=exact, 4=advanced, -1 to -4=Nocase

Global $ExitID

_Main()

Func _Main()
    Local $ScrCapID

    GUICreate("ScrCap", 160, 40)

    $ScrCapID = GUICtrlCreateButton("Capture", 40, 10, 80, 20)
    GUICtrlSetOnEvent($ScrCapID, "OnScrCap")

    GUISetOnEvent($GUI_EVENT_CLOSE, "OnExit")

    GUISetState()  ; display the GUI
    WinSetOnTop("ScrCap", "", 1)

    While 1
        Sleep(1000)
    WEnd
EndFunc   ;==>_Main

;--------------- Functions ---------------
Func OnScrCap()
    Local $tTime, $aTime
    WinSetState("ScrCap", "", @SW_HIDE)
    ;Sleep(250)
    $tTime = _Date_Time_GetSystemTime()
    $aTime = _Date_Time_SystemTimeToArray($tTime)
    _ScreenCapture_Capture(@MyDocumentsDir & "\" & StringFormat("ScrCap%04i%02i%02i%02i%02i%02i%03i", $aTime[2], $aTime[0], $aTime[1], $aTime[3], $aTime[4], $aTime[5], $aTime[6]) & ".jpg", 0, 0, -1, -1, False)
    WinSetState("ScrCap", "", @SW_SHOW)
EndFunc   ;==>OnScrCap

Func OnExit()
    Exit
EndFunc   ;==>OnExit

| | コメント (0) | トラックバック (0)

« 2010年4月 | トップページ | 2012年3月 »